Жанр: Учеба
Справочник программиста на IBM PC
...локов файла, а другая -
для файлов, открытых методом дескриптора файлов. Одна из функций
каждой пары ищет первое появление имени файла в каталоге, а другая
ищет последующие появления, когда в имени файла содержатся
джокеры. Только метод, использующий дескриптор файла позволяет
искать подкаталоги.
Метод FCB:
Функция 11H прерывания 21H ищет первое появление файла. Установите
DS:DX на неоткрытый FCB и выполните функцию. При возврате
AL будет содержать 0, если файл найден, и FF - если нет. DTA
заполняется информацией из каталога. Для обычных FCB первый байт
DTA содержит номер накопителя (1 = A и т.д.), а следующие 32
байта содержат элемент каталога. Для расширенного FCB первые 7
байтов файла копируются в первые 7 байтов расширенного FCB, восьмой
байт указывает на накопитель, а следующие 32 байта - элемент
каталога.
;---в сегменте данных
FCB DB 1,'NEWDATABAK',25DUP(0)
;---ищем файл
MOV AH,11H ;функция поиска в каталоге
LEA DX,FCB ;указываем на FCB
INT 21H ;ищем
CMP AL,0 ;успешно?
JNE NO_FILE ;если нет, то процедура обработки ошибки
LEA BX,DTA ;теперь DS:BX указывает на элемент каталога
После использования функции 11H можно использовать функцию 12H
для поиска следующих подходящих элементов, когда имя файла содержит
джокеры. В данном случае в имени файла допустим только символ
"?", но не "*". Эта функция работает в точности так же, как и
первая, и если найден второй файл, то информация о первом файле в
DTA будет уничтожена повторной записью.
Метод дескриптора файлов:
Функция 4EH прерывания 21H ищет файл с данным именем. DS:DX
должны указывать на строку, дающую путь файла. Например, B:\EUROPE\FRANCE\PARIS
указывает на файл PARIS. Строка может содержать
до 63 символов и завершаться символом ASCII 0. Имя файла может
содержать джокеры, включая как "?", так и "*". Поместите атрибут
файла в CX; если он обычный то 0, в противном случае проконсультируйтесь
в [5.2.6] относительно значений атрибута.
При возврает устанавливается флаг переноса, если файл не найден.
Если файл найден, то функция заполняет DTA информацией о
файле. Отметим частный случай использования DTA методом дескриптора
файлов - обычно, DTA используется функциями MS DOS для работы
через FCB. Первые 21 байт DTA зарезервированы DOS для поиска
следующих совпадающих файлов. Двадцать второй байт дает атрибут
файла, за ним следуют два байта, содержащие время и еще два байта
содержащие дату. Следующие 4 байта содержат размер файла (младшее
слово сначала). И, наконец, дается имя файла в виде строки переменной
длины, заканчивающейся байтом ASCII 0. Точка (ASCII 46)
разделяет имя и расширение и не один из этих элементов не заполнен
пробелами.
;---в сегменте данных
PATH DB 'B:FRANCE\PARIS\4EME',0
;---ищем файл
MOV AH,4EH ;номер функции
LEA DX,PATH ;DS:DX указывают на путь
MOV CX,0 ;обычный атрибут файла
INT 21H ;ищем файл
JC NO_FILE ;уход, если не найден
LEA BX,DTA ;DS:BX указывают на DTA
MOV AL,[BX]+21 ;теперь атрибут файла в AL
Следующее появление имени файла (когда используются джокеры)
ищется с помощью функции 4FH прерывания 21H. Она готовится в
точности так же, как и функция 4EH, при этом указатель DTA не
должен меняться. Когда других совпадений не найдено, то устанавливается
флаг переноса, а в AX появляется 18.
5.2.2 Создание/удаление подкаталога.
Программа может создавать или удалять подкаталоги, при выполнении
некоторых условий. Для создания подкаталога необходимо,
чтобы было по крайней мере одно пустое место в корневом каталоге.
Для удаления подкаталога необходимо, чтобы он не содержал файлов
или ссылок на другие подкаталоги. Кроме того, Вы не можете удалить
подкаталог, который является Вашим текущим каталогом (тот, с
которым по умолчанию выполняются все операции над каталогами).
Отметим также, что невозможно удалить корневой каталог.
Высокий уровень.
Бейсик предоставляет команды MKDIR (создай каталог) и RMDIR
(удали каталог). За обеими должны следовать стандартные пути
указания каталога, содержащие до 63 символов, включая имя накопителя.
Путь должен быть заключен в кавычки. Чтобы добавить подкаталог
с именем STORKS в подкаталог BIRDS напишите MKDIR "B:MAMMALS\BIRDS\STORKS".
После выполнения этой команды будет создан
файл STORKS, используемый как подкаталог и факт его существования
будет отражен в создании элемента с именем STORKS в подкаталоге с
именем BIRDS. Для удаления этого подкаталога надо сначала удалить
из него все файлы [5.3.2]. Затем надо использовать команду RMDIR
"B:MAMMALS\BIRDS\STORKS".
В этих примерах предполагалось, что Вашим текущим каталогом
являлся корневой каталог. Однако, если Ваш текущий каталог находится
где-то на пути к подкаталогу, над которым осуществляются
операции, то нет необходимости указывать весь путь. Поэтому, если
Вашим текущим каталогом является BIRDS, то для создания или удаления
подкаталога STORKS можно использовать команды MKDIR
"\STORKS" или RMDIR "\STORKS".
Средний уровень.
Поскольку управляющие блоки файлов обслуживают только корневой
каталог, то для создания или удаления подкаталога надо использовать
дескрипторы файлов.
Создание подкаталога:
DS:DX должны указывать на строку, дающую накопитель и путь к
каталогу, в котором должен быть создан подкаталог. Строка должна
завершаться байтом ASCII 0. Для открытия подкаталога с именем
PRIMATES в корневом каталоге накопителя A: надо записать строку в
виде "A:\PRIMATES". Для открытия подкаталога в другом подкаталоге
с именем MAMMALS напишите "A:\MAMMALS\PRIMATES". Имя накопителя
A: может быть опущено если Вы работаете с накопителем, используемым
по умолчанию, и путь может начинаться с текущего каталога.
Поместите в AH 39H и выполните прерывание 21H; если указан правильный
путь, то будет создан новый каталог. В противном случае
будет установлен флаг переноса, а AX будет содержать код ошибки 3
(путь неверен) или 5 (нет доступа). В примере создается подкаталог
PRIMATES:
;---в сегменте данных
PATH DB 'A:MAMMALS\PRIMATES',0
;---создаем подкаталог с именем PRIMATES
LEA DX,PATH ;DS:DX должны указывать на путь
MOV AH,39H ;номер функции
INT 21H ;создаем подкаталог
JC ERROR_ROUT ;обработка ошибок
Удаление подкаталога:
Для удаления подкаталога надо сформировать строку, в точностью
совпадающую с той, которую Вы указывали при создании каталога.
Затем поместите в AH 3AH и выполните прерывание 21H. Опять при
невыполнении функции в AX будут возвращены коды 3 или 5 (код 5
может указывать, что каталог непустой).
5.2.3 Чтение/изменение подкаталога.
Подкаталоги во многом подобны корневому каталогу, за исключением
того, что они хранятся как обычные файлы, а не в заранее
предопределенных секторах. Подкаталоги невозможно спутать с обычными
файлами, поскольку объект каталога, относящийся к подкаталогу,
имеет специальный байт атрибутов (с установленным битом 5 -
см. [5.2.6]). Подкаталоги начинаются с двух специальных 32-байтных
объектов, первый из которых имеет имя точка, а второй - две
точки. Они ориентируют подкаталог среди окружающих каталогов.
Ссылки на подкаталоги нижнего уровня записываются как обычные
ссылки на файлы.
Предполагается, что подкаталог может быть прочитан как любой
другой файл, поэтому вроде бы не составляет труда загрузить его в
память. Но, к сожалению, создатели MS DOS поместили 0 в поле
длины файла для элементов, относящихся к подкаталогам. В результате
DOS считает, что этот файл имеет нулевую длину и отказывается
читать его. Нет простого способа преодолеть эту проблему.
Высокий уровень.
В Бейсике команда FILES может использовать стандартные имена
путей для вывода подкаталога; например, FILES "B:MAMMALS\BIRDS"
выводит все файлы, содержащиеся в подкаталоге BIRDS. Эта команда
может быть использована и для получения информации о наличии в
каталоге определенного файла. Например, FILES "LEVEL1\NEWDATA"
ищет файл NEWDATA и выводит его имя, если он найден. Хотя это
может быть полезным для пользователя, но часто самой программе
необходимо знать существует или нет указанный файл. Чтобы установить
это попытайтесь открыть файл для последовательного чтения.
Если он не будет найден, то возникнет ошибочное условие 63. Создайте
процедуру обработки ошибок, как описано в [5.4.8]. Затем
используйте переменную, чтобы отметить был ли найден требуемый
файл (в нашем примере переменная "EXISTS"). Если программе не
нужно, что этот файл был открыт, то закройте его перед тем как
двинуться дальше.
100 ON ERROR GOTO 1000 'процедура обработки ошибок
110 EXISTS = 1 'начальное значение "флага"
120 INPUT "Enter filename: ",S$ 'запрос имени файла
130 OPEN S$ FOR INPUT AS #3 'открываем его для послед. чтения
140 IF EXISTS = 0 THEN BEEP: PRINT "File does not exist"
1000 IF ERR = 53 THEN 1500 'файл не существует?
1010 IF ERR = 64 THEN ... 'другие ошибки
1500 EXISTS = 0 'меняем значение флага
1510 RESUME 140 'продолжаем выполнение программы
Средний уровень.
Функции работы через дескрипторы файлов, которые использовались
для доступа к корневому каталогу [5.2.1] могут так же просто
обращаться к любому подкаталогу. Чтобы вывести все содержимое
каталога надо просто использовать функцию 4EH для поиска файлов
*.*, а затем повторять поиск, используя функцию 4FH. Когда больше
не будет файлов, то будет установлен флаг переноса, а AL будет
содержать 18. Каждый раз, когда будет обнаружен очередной элемент,
в DTA будет записана информация о файле, включая полный его
путь (отмечаем использование DTA в функциях, использующих дескриптор
файла). Следующий пример выводит полные пути всех обычных
файлов подкаталога.
;---в сегменте данных
PATH DB 'A:MAMMALS\*.*',0
DTAH DB 256 DUP(?)
;---установка DTA
LEA DX,DTA ;DS:DX указывают на DTA
MOV AH,1AH ;функция установки DTA
INT 21H ;устанавливаем DTA
;---ищем первый файл
MOV AH,4EH ;номер функции
LEA DX,PATH ;указываем на строку пути
MOV CX,0 ;только нормальные атрибуты
INT 21H ;ищем *.*
JC ERROR ;обработка ошибок
;---выводим имя файла
NEXT_LINE: LEA BX,DTA ;BX указывает на DTA
ADD BX,30 ;смещение для имени файла
NEXT_CHAR: MOV DL,[BX] ;получаем символ из имени
CMP DL,0 ;проверка на конец строки
JE END_STR ;уход, если конец
MOV AH,2 ;иначе, выодим символ
INT 21H ;
INC BX ;увеличиваем указатель
JMP SHORT NEXT_CHAR ;следующий символ
;---возврат каретки/перевод строки в конце строки
END_STR: MOV AH,2 ;функция вывода символа
MOV DL,13 ;код возврата каретки
INT 21H ;выводим
MOV DL,10 ;код перевода строки
INT 21H ;выводим
;---ищем следующий файл
LEA DX,PATH ;указываем на строку пути
MOV AH,4FH ;номер функции
INT 21H ;ищем следующий файл
JC FINISHED ;если нет, то выход
JMP SHORT NEXT_LINE ;иначе выводим имя файла
FINISHED:
5.2.4 Получение/установка текущего каталога.
Текущий каталог это каталог, в котором DOS ищет файл, для
которого не указан путь. Если не установлено противного, то текущий
каталог является корневым каталогом.
Высокий уровень.
Бейсик устанавливает текущий каталог с помощью команды CHDIR.
За командой должна следовать строка, указывающая путь к каталогу,
на который надо перейти. Строка может содержать до 63-х символов,
включая имя накопителя, и должна быть заключена в кавычки. CHDIR
"C:MAMMALS\PRIMATES\GIBBONS" делает подкталог GIBBONS текущим
каталогом. Чтобы перейти в корневой каталог напишите CHDIR "\"
или CHDIR "B:\".
Бейсик версии 3.0 может сообщать путь к текущему каталогу, как
это делает команда DOS PATH. Просто введите PRINT ENVIRON$("PATH").
Средний уровень.
Функция 3BH прерывания 21H устанавливает текущий каталог.
DS:DX должны указывать на путь к каталогу в стандартном виде и
эта строка должна завершаться байтом ASCII 0. Например, B:BIRDS\-
PARROTS\POLLY делает POLLY текущим каталогом. B: может быть опущено,
если это текущий накопитель по умолчанию [5.3.1]. Чтобы
сделать текущим корневой каталог накопителя A: напишите A:\. В
примере текущим каталогом устанавливается POLLY:
;---в сегменте данных
PATH DB 'B:BIRDS\PARROTS\POLLY',0
;---делаем POLLY текущим каталогом
MOV AH,3BH ;номер функции
LEA DX,PATH ;DS:DX должны указывать на путь
INT 21H ;устанавливаем текущий каталог
Чтобы определить какой каталог является текущим надо использовать
функцию 47H прерывания 21H. DS:SI должны указывать на область
данных размером 64 байта, в которую будет записан путь. В
DL указывается накопитель, причем 0 = "по умолчанию", 1 = A, 2 =
B и т.д. При возврате функция возвращает строку без имени накопителя.
Если был указан несуществующий накопитель, то в AL возвращается
код ошибки 15. Строка начинается с имени первого подкаталога
цепочки, а не с обратной косой черты. Байт ASCII 0 сигнализирует
о конце строки. В данном примере имя текущего каталога
присваивается переменной "CURRENT_DIR":
;---в сегменте данных
CURRENT_DIR DB 64 DUP(?)
;---получить текущий каталог
MOV AH,47H ;номер функции
LEA SI,CURRENT_DIR ;указываем на область данных
MOV DL,1 ;накопитель A
INT 21H ;помещает строку по адресу DS:SI
5.2.5 Получение/установка времени и даты последнего доступа к
файлу.
Если отсчитывать от нуля, то байты 22-23 32-байтного элемента
каталога содержат время последнего доступа к файлу. Байты 24-25 -
содержат дату. Значение битов следующее:
Время: биты 11-15 часы (0-23)
5-10 минуты (0-59)
0-4 секунды (0-29 с 2-секундным интервалом)
Дата: биты 9-15 год (0-119, смещение с 1980 года)
5-8 месяц (1-12)
0-4 число (1-31)
День недели не записывается; DOS вычисляет его по остальной информации.
Отметим также, что как всегда, младший байт этих
2-байтных значений расположен раньше в памяти, чем старший.
Средний уровень.
Метод доступа к файлу с использованием управляющего блока
файла позволяет получить дату последнего доступа к файлу, но не
время. Когда FCB открывается функцией 0FH прерывания 21H, то
заполняется двухбайтное поле даты в вышеприведенном формате. Это
поле расположено в FCB со смещением 14H [5.3.5].
С другой стороны, доступ к файлу с помощью дескриптора файла
позволяет как получить, так и установить дату и время последнего
доступа к файлу. Функция 57H прерывания 21H выполняет все операции.
Для установки времени и даты поместите номер файла в BX, и 0
в AL. Для получения даты и времени надо поместить в AL 1. В обоих
случаях дата содержится в DX, а время в CX. Значение битов совпадает
с тем, что описано в таблице. В техническом руководстве по
MS DOS утверждается, что младшие байты информации находятся в CH
и DH, и наоборот. На самом деле это не так. При возникновении
ошибки устанавливается флаг переноса, а в AX возвращается 1, если
в AL указано неправильное число и 6, если плохой дескриптор файла.
В следующем примере определяется час, в который был последний
лоступ к файлу:
;---в сегменте данных
PATH DB 'B:NEWDATA.BAK',0
;---открываем файл
LEA DX,PATH ;указываем на строку пути
MOV AH,3DH ;функция открытия файла
MOV AL,0 ;открываем для чтения
INT 21H ;открываем файл
JC OPEN_ERROR ;переход на обработку ошибки
;---получаем дату и время доступа к файлу
MOV BX,AX ;помещаем номер файла в BX
MOV AL,0 ;код для чтения времени
MOV AH,57H ;номер функции
INT 21H ;получаем время доступа
JC TIME_ERROR ;переход на обработку ошибок
;---сдвигаем биты, относящиеся к часам, в начало CH
MOV CL,3 ;готовим сдвиг
SHR CH,CL ;теперь CH содержит час доступа
5.2.6 Спрятанные и защищенные от записи файлы.
DOS использует шесть различных атрибутов файлов, которые дают
данному файлу определенный статус. Файл может иметь несколько из
этих атрибутов одновременно (но не все). Атрибуты устанавливаются
12-м байтом 32-байтного элемента каталога. Младшие шесть битов
имеют значение, а остальные должны быть равны нулю. Биты такие:
если бит 5 = 1, то файл был изменен со времени последней
архивации
4 = 1, то файл является подкаталогом
3 = 1, то этот элемент является не файлом, а меткой
тома
2 = 1, то файл является "системным"
1 = 1, то файл спрятан при поиске по каталогу
0 = 1, то файл объявлен только для чтения
Бит 5 это архивный бит, используемый программами BACKUP и RESTORE
DOS. Этот бит сьрасывается в 0 после архивации и устанавливается,
когда с файлом снова работали. При следующей архивации неизмененные
файлы могут быть обнаружены и проигнорированы.
Высокий уровень.
Бейсик не позволяет Вам устанавливать атрибуты файла прямо.
Справьтесь в [5.2.1], как считать каталог в память, найти нужный
файл, сделать изменения и снова записать его на диск. Как только
каталог помещается в память, байты атрибутов находятся по смещениям
11, 43, 75 и т.д. Если нужно, то Вы можете прочитать текущие
атрибуты и изменить только один бит, используя технику битовых
операций, описанную в приложении Б. Но легче просто переписать
все атрибуты заново. Будьте внимательны, ошибки могут быть фатальными.
В данном примере считываются атрибуты файла с именем
"NEWDATA.AAA".
100 'читаем сектора каталога, начиная с &H2000 и затем ...
110 DEF SEG = &H2000 'указываем на область каталога
120 FILENAME$ = "NEWDATAAAA" 'ищем имя файла без точки
130 DIRPTR = 0 'указатель в каталоге
140 FOR N = 1 TO 112 'проверяем все элементы
150 X$ = "" 'временная строка для имени файла
160 FOR M = 0 TO 10 'для каждого символа имени
170 X$ = X$+PEEK(DIRPTR+M) 'добавляем его к строке
180 NEXT '
190 IF X$ = FILENAME$ THEN 220 'если имя найдено, то уходим
200 NEXT '
210 PRINT "File not found": END 'нет такого файла
220 X = PEEK(DIRPTR+11) 'получаем атрибуты нужного файла
230 IF X AND 32 "" 0 THEN PRINT "File not baked up"
240 IF X AND 16 "" 0 THEN PRINT "File is a subdirectory"
250 IF X AND 8 "" 0 THEN PRINT "Volume label - not a file"
260 IF X AND 4 "" 0 THEN PRINT "File is a system file"
270 IF X AND 2 "" 0 THEN PRINT "File is a hidden file"
280 IF X AND 1 "" 0 THEN PRINT "File is read-only"
Средний уровень.
Функция 43H прерывания 21H может как находить, так и изменять
атрибуты файла, но только если файл был открыт с помощью метода
дескриптора файлов, а не с помощью метода управляющего блока
файла. Нет аналогичной функции для FCB. Байт атрибутов может быть
установлен при создании файла [5.3.2], используя расширенный
управляющий блок файла. Но если Вы последовательно откроете FCB,
измените установку атрибутов и затем закроете файл, то у него
останутся первоначальные атрибуты. Хотя, конечно, Вы можете изменить
атрибуты каким-нибудь обходным путем, но намного проще использовать
функцию, использующую метод дескриптора файлов.
Чтобы использовать функцию 43H, поместите 1 в AL, чтобы присвоить
файлу байт атрибутов, содержащийся в CX (на самом деле в
CL, поскольку CH равен 0). Можно наоборот поместить в AL 0, чтобы
в CX был возвращен текущий байт атрибутов файла. В обоих случаях
DS:DX должны указывать на строку, дающую путь к файлу. Конец
строки отмечается байтом ASCII 0 (который не входит в число 63-х
символов). В примере статус "hidden" (спрятанный) присваивается
файлу OVERDUE:
;---в сегменте данных
PATH DB 'A:ACCOUNTS',0
;---включаем признак спрятанного файла
MOV AH,43H ;номер функции
MOV AL,0 ;читаем байт атрибутов
LEA DX,PATH ;DS:DX указывают на путь
INT 21H ;байт атрибутов в CX
JC ERROR_ROUTINE ;обработка ошибок
OR CL,10B ;включаем бит 1
MOV AH,43H ;номер функции
MOV AL,1 ;заменяем байт атрибутов
INT 21H ;теперь файл стал спрятанным
Флаг переноса устанавливается при возникновении ошибки. В этом
случае в AX возвращается 2 - если файл не найден, 3 - если не
найден путь и 5 - при других ошибках (нет доступа).
5.2.7 Чтение/изменение метки тома.
Метка тома для дискеты - это элемент каталога, имеющий специальный
атрибут. Метка занимает первые 11 байтов элемента, относящиеся
к имени и расширению файла. Байт атрибутов по смещению 11
содержит значение 8 (бит 3 = 1). Поля времени и даты заполняются
обычным образом. Одним из свойств этого атрибута является то, что
данный элемент не выводится по команде DIR.
Метка может занимать любую позицию в каталоге. Она ищется
перебором всех байтов атрибутов, пока не будет найдено значение
8. Чтобы стереть метку надо просто поместить E5 в первый байт
соответствующего элемента - сам байт атрибутов можно не менять.
Чтобы изменить метку надо записать новые 11 символов (остаток
надо заполнить пробелами). Чтобы присвоить метку тома диску,
который не имел ее, надо найти пустое место в каталоге и записать
туда метку и соответствующий атрибут, ничего больше не требуется.
Высокий уровень.
Обсуждение в [5.4.2] объясняет как читать и писать абсолютные
сектора в Бейсике. Для стандартной двухсторонней дискеты надо
использовать номер стороны 0, номер дорожки 0, номер сектора - 6
и число секторов для чтения/записи - 7. После того, как данные
записаны в отведенный буфер, примеры, приведенные здесь могут
быть использованы для изменения или добавления метки тома. Затем
сектора должны быть перезаписаны на диск. Будьте внимательны:
ошибка может привести к потере всей информации на диске. Данный
пример ищет метку тома и изменяет ее:
100 'сектора загружены, начиная скажем с &H1000
110 DEF SEG = &H1000
120 DIRPTR = 11 'указатель на байт атрибутов
130 FOR N = 1 TO 112 'проверяем все элементы каталога
140 IF PEEK(DIRPTR) = 8 THEN 180 'уход если метка тома
150 DIRPTR = DIRPTR + 32 'указываем на след. элемент
160 NEXT 'проверяем его атрибут
170 PRINT "No volume label found": END 'метки нет
180 INPUT "Enter new volume label", V$ 'запрос метки
190 IF LEN(V$) " 11 THEN BEEP: PRINT "11 chars only": GOTO 180
200 V$ = V$ + STRING$(11-LEN(V$),32) 'дополняем пробелами
210 DIRPTR = DIRPTR - 11 'возвращаемся на начало элемента
220 FOR N = 1 TO LEN(V$) 'помещаем все символы метки
230 POKE N,MID$(V$,N,1) 'в память
240 NEXT '
250 'теперь осталось перезаписать сектора на диск
Низкий уровень.
В нижеприведенном примере предполагается, что Вы создали буфер
данных размером 3584 байт, для хранения всех семи секторов каталога
дискеты емкостью 360K. Буфер называется DIR_AREA. В первом
примере метка тома ищется и выводится, или, если она не найдена,
то выводится сообщение об ее отсутствии. Для удобства область
буфера для секторов отводится в сегменте данных; лучше отвести
память для задачи, а затем освободить ее [1.3.1].
;---в сегменте данных
VOL_STRING DB 'The volume label is $'
NO_LABEL DB 'There is no volume label $'
DIR_AREA DB 3584 DUP(?)
;---читаем 7 секторов каталога
MOV AX,SEG DIR_AREA ;сегмент буфера
MOV ES,AX ;
MOV BX,OFFSET DIR_AREA ;смещение буфера
MOV DL,0 ;номер накопителя
MOV DH,0 ;номер головки
MOV CH,0 ;номер дорожки
MOV CL,6 ;стартовый сектор
MOV AL,7 ;число секторов каталога
MOV AH,2 ;номер функции чтения
INT 13H ;читаем каталог в память
;---ищем метку тома, сравнивая байт атрибутов с 8
MOV CX,112 ;число элементов
ADD BX,11 ;смещение для атрибутов
TRY_AGAIN: MOV AL,[BX] ;берем 1-й элемент
CMP AL,8 ;это метка тома?
JE GOT_IT ;если да, то уход
ADD BX,32 ;иначе на след. элемент
LOOP TRY_AGAIN ;
;---выводим сообщение об отсутствии метки тома
MOV AH,9 ;функция вывода строки
LEA DX,NO_LABEL ;указываем на строку
INT 21H ;выводим ее
JMP SHORT CONTINUE ;на конец
;---выводим строку, дающую метку тома
GOT_IT: MOV AH,9 ;функция вывода строки
LEA DX,VOL_STRING ;указываем на строку
INT 21H ;выводим ее
SUB BX,11 ;указатель на метку
MOV CX,11 ;пишем 11 символов
MOV AH,2 ;функция вывода символов
NEXT_CHAR: MOV DL,[BX] ;символ в DL
INT 21H ;выводим символ
INC BX ;переходим к следующему
LOOP NEXT_CHAR ;
CONTINUE:
Чтобы стереть метку поместите следующий код в GOT_IT:
GOT_IT: MOV AL,0E5H ;код отметки пустого элемента
SUB BX,11 ;указатель на начало элемента
MOV [BX],AL ;меняем первый байт
Чтобы изменить метку тома, надо вместо этого использовать в
GOT_IT следующий код. Предполагается, что Вы подготовили где-то
11-байтную строку NEW_LABEL.
GOT_IT: LEA SI,NEW_LABEL ;SI должен указывать на строку
SUB BX,11
...Поділитися у соцмережах
